Fortran 动态数组

动态数组是一个数组，其大小在编译时未知，但在执行时已知。

动态数组使用属性 allocatable 声明。

例如：

real, dimension (:,:), allocatable :: darray

数组的维度，必须提及，但是，要为这样的数组分配内存，您可以使用 allocate 函数。

allocate ( darray(s1,s2) )

使用数组后，在程序中，应使用解除分配函数释放创建的内存。

deallocate (darray)

实例

program dynamic_array
implicit none
   !rank is 2, but size not known
   real, dimension (:,:), allocatable :: darray
   integer :: s1, s2
   integer :: i, j
   print*, "Enter the size of the array:"
   read*, s1, s2
   ! allocate memory
   allocate ( darray(s1,s2) )
   do i = 1, s1
      do j = 1, s2
         darray(i,j) = i*j
         print*, "darray(",i,",",j,") = ", darray(i,j)
      end do
   end do
   deallocate (darray)
end program dynamic_array

结果如下：

Enter the size of the array: 3,4
darray( 1 , 1 ) = 1.00000000
darray( 1 , 2 ) = 2.00000000
darray( 1 , 3 ) = 3.00000000
darray( 1 , 4 ) = 4.00000000
darray( 2 , 1 ) = 2.00000000
darray( 2 , 2 ) = 4.00000000
darray( 2 , 3 ) = 6.00000000
darray( 2 , 4 ) = 8.00000000
darray( 3 , 1 ) = 3.00000000
darray( 3 , 2 ) = 6.00000000
darray( 3 , 3 ) = 9.00000000
darray( 3 , 4 ) = 12.0000000

数据声明的使用

数据语句可用于初始化多个数组，或用于数组段初始化。

数据语句的语法为：

data variable / list / ...

实例

program dataStatement
implicit none
   integer :: a(5), b(3,3), c(10),i, j
   data a /7,8,9,10,11/
   data b(1,:) /1,1,1/
   data b(2,:)/2,2,2/
   data b(3,:)/3,3,3/
   data (c(i),i = 1,10,2) /4,5,6,7,8/ 
   data (c(i),i = 2,10,2)/5*2/
   Print *, 'The A array:'
   do j = 1, 5
      print*, a(j)
   end do
   Print *, 'The B array:'
   do i = lbound(b,1), ubound(b,1)
      write(*,*) (b(i,j), j = lbound(b,2), ubound(b,2))
   end do
   Print *, 'The C array:'
   do j = 1, 10
      print*, c(j)
   end do
end program dataStatement

结果如下：

 The A array:
           7
           8
           9
          10
          11
 The B array:
           1           1           1
           2           2           2
           3           3           3
 The C array:
           4
           2
           5
           2
           6
           2
           7
           2
           8
           2

Where 语句的使用

where 语句可以让您在表达式中使用数组的某些元素，具体取决于某些逻辑条件的结果。如果给定的条件为 true，它允许在元素上执行表达式。

实例

program whereStatement
implicit none
   integer :: a(3,5), i , j
   do i = 1,3
      do j = 1, 5
         a(i,j) = j-i
      end do
   end do
   Print *, 'The A array:'
   do i = lbound(a,1), ubound(a,1)
      write(*,*) (a(i,j), j = lbound(a,2), ubound(a,2))
   end do
   where( a<0 )
      a = 1
   elsewhere
      a = 5
   end where
   Print *, 'The A array:'
   do i = lbound(a,1), ubound(a,1)
      write(*,*) (a(i,j), j = lbound(a,2), ubound(a,2))
   end do
end program whereStatement

结果如下：

 The A array:
           0           1           2           3           4
          -1           0           1           2           3
          -2          -1           0           1           2
 The A array:
           5           5           5           5           5
           1           5           5           5           5
           1           1           5           5           5