Fortran 数组

数组可以存储固定大小的相同类型元素的顺序集合。数组用于存储数据集合，但将数组视为同一类型的变量集合通常更有用。

所有数组都由连续的内存位置组成。最低地址对应于第一个元素，最高地址对应于最后一个元素。

Numbers(1)    Numbers(2)    Numbers(3)    Numbers(4)    …

数组可以是一维（如向量）、二维（如矩阵），Fortran 可以创建多达 7 维的数组。

声明数组

数组是用维度属性声明的。

例如，要声明一个名为 number 的一维数组，其中包含 5 个元素的实数，你可以写：

real, dimension(5) :: numbers

通过指定下标来引用数组的各个元素。数组的第一个元素的下标为 1。数组数字包含五个实变量——数字（1）、数字（2）、数字。

要创建一个名为 matrix 的 5 x 5 二维整数数组，你可以写：

integer, dimension (5,5) :: matrix

您还可以声明一个具有明确下限的数组，例如：

real, dimension(2:6) :: numbers
integer, dimension (-3:2,0:4) :: matrix

赋值

您可以为单个成员分配值，例如：

numbers(1) = 2.0

或者你可以使用循环：

do i  =1,5
   numbers(i) = i * 2.0
end do

一维数组元素可以使用称为数组构造函数的简写符号直接赋值，例如，

numbers = (/1.5, 3.2,4.5,0.9,7.2 /)

实例

以下实例演示了上面讨论的概念。

program arrayProg
   real :: numbers(5) !one dimensional integer array
   integer :: matrix(3,3), i , j !two dimensional real array
   !assigning some values to the array numbers
   do i=1,5
      numbers(i) = i * 2.0
   end do
   !display the values
   do i = 1, 5
      Print *, numbers(i)
   end do
   !assigning some values to the array matrix
   do i=1,3
      do j = 1, 3
         matrix(i, j) = i+j
      end do
   end do
   !display the values
   do i=1,3
      do j = 1, 3
         Print *, matrix(i,j)
      end do
   end do
   !short hand assignment
   numbers = (/1.5, 3.2,4.5,0.9,7.2 /)
   !display the values
   do i = 1, 5
      Print *, numbers(i)
   end do
end program arrayProg

结果如下：

 2.00000000
 4.00000000
 6.00000000
 8.00000000
 10.0000000
         2
         3
         4
         3
         4
         5
         4
         5
         6
 1.50000000
 3.20000005
 4.50000000
0.899999976
 7.19999981

一些与数组相关的术语

下表给出了一些与数组相关的术语：

将数组传递给程序

您可以将数组作为参数传递给过程。以下实例演示了该概念：

program arrayToProcedure
implicit none
   integer, dimension (5) :: myArray
   integer :: i
   call fillArray (myArray)
   call printArray(myArray)
end program arrayToProcedure
subroutine fillArray (a)
implicit none
   integer, dimension (5), intent (out) :: a
   ! local variables
   integer :: i
   do i = 1, 5
      a(i) = i
   end do
end subroutine fillArray
subroutine printArray(a)
   integer, dimension (5) :: a
   integer::i
   do i = 1, 5
      Print *, a(i)
   end do
end subroutine printArray

结果如下：

1
2
3
4
5

在上面的实例中，子例程 fillArray 和 printArray 只能对维度为 5 的数组调用。但是，要编写可用于任何大小数组的子程序，您可以使用以下技术重写它：

program arrayToProcedure
implicit  none
   integer, dimension (10) :: myArray
   integer :: i
   interface
      subroutine fillArray (a)
         integer, dimension(:), intent (out) :: a
         integer :: i
      end subroutine fillArray
      subroutine printArray (a)
         integer, dimension(:) :: a
         integer :: i
      end subroutine printArray
   end interface
   call fillArray (myArray)
   call printArray(myArray)
end program arrayToProcedure
subroutine fillArray (a)
implicit none
   integer,dimension (:), intent (out) :: a
   ! local variables
   integer :: i, arraySize
   arraySize = size(a)
   do i = 1, arraySize
      a(i) = i
   end do
end subroutine fillArray
subroutine printArray(a)
implicit none
   integer,dimension (:) :: a
   integer::i, arraySize
   arraySize = size(a)
   do i = 1, arraySize
     Print *, a(i)
   end do
end subroutine printArray

结果如下：

1
2
3
4
5
6
7
8
9
10

部分数组

到目前为止，我们已经引用了整个数组，Fortran 提供了一种使用单个语句引用多个元素或数组一部分的简单方法。

要访问部分数组，您需要为所有维度提供该部分的下限和上限，以及增量。这种符号称为下标三元组：

array ([lower]:[upper][:stride], ...)

当没有提到下限和上限时，它默认为您声明的范围，增量值默认为 1。

以下实例演示了该概念：

program arraySubsection
   real, dimension(10) :: a, b
   integer:: i, asize, bsize
   a(1:7) = 5.0 ! a(1) to a(7) assigned 5.0
   a(8:) = 0.0  ! rest are 0.0
   b(2:10:2) = 3.9
   b(1:9:2) = 2.5
   !display
   asize = size(a)
   bsize = size(b)
   do i = 1, asize
      Print *, a(i)
   end do
   do i = 1, bsize
      Print *, b(i)
   end do
end program arraySubsection

结果如下：

5.00000000
5.00000000
5.00000000
5.00000000
5.00000000
5.00000000
5.00000000
0.00000000E+00
0.00000000E+00
0.00000000E+00
2.50000000
3.90000010
2.50000000
3.90000010
2.50000000
3.90000010
2.50000000
3.90000010
2.50000000
3.90000010

数组固有函数

Fortran 90/95 提供了几个内置程序。它们可分为 7 类：

• Vector 和 matrix multiplication
• Reduction
• Inquiry
• Construction
• Reshape
• Manipulation
• Location